set terminal postscript eps color enhanced font "arial,16" size 8.6cm,6cm
set encoding utf8

set output "g2X_laser.eps"

# raw data and equation of fit by python script
raw_data_1="g2X_laser.dat"
fitted_data_1="g2X_laser_fitted.dat"

# some plot parameters?
symbols_color_1 = "#0000FF"
time_offset = 157.27 #bin number
bin_size = 2 #ns

# set yrange to scale g2 to normalised with coincidences
laser_lower_range = 0.50
laser_upper_range = 1.05
laser_normalisation_factor = 0.000076

# set y2range to scale coincidences with g2 range
laser_lower_y2_range = 0.50*13116.5
laser_upper_y2_range = 1.05*13116.5

set xrange [-0.6:0.6] # microseconds
set yrange [laser_lower_range:laser_upper_range]
set xlabel "coincidence timing separation {/Symbol t} ({/Symbol m}s)"
set bars large
set ylabel "g^{(2X)}({/Symbol t})"
set ytics nomirror 0.5,0.1,1.0 format "%.2f"
set y2tics nomirror 7000,1000,14000 format "%.0f"
set y2label "coincidences" 
set y2range [laser_lower_y2_range:laser_upper_y2_range]

plot raw_data_1 using ($1-time_offset)*bin_size*0.001:($3):(sqrt($2)/$2*$3) with yerrorbars linestyle 6 ps 0.9 linetype rgb symbols_color_1 notitle,fitted_data_1 using ($1*0.001):($3) with lines lw 2 linetype rgb "#000000" notitle