reset
set term postscript enhanced landscape color font "Helvetica,24pt" dashlength 2.0
set size 1,0.8
#set term pngcairo
st='lt 2 lw 2'
PI=3.14159

set xrange [0:8]
set yrange [0:7]
set ytics nomirror
set ytics ("0" 0, "{/Symbol p}/2" PI/2 ,"{/Symbol p}" PI, "2{/Symbol p}" 2*PI, "3{/Symbol p}/2" 3*PI/2)
set xlabel "Amplitude (Volts)"
set ylabel "Retardance (Rad)"

#shaded box covering the actual voltage range
set style rect fc lt -1 fs solid 0.15 noborder
set obj rect from 1,0 to 6,7

f(x)=a*exp(-b*x+c)+d
#f(x)=a*x**5+b*x**4+c*x**3+d*x**2+e*x+f

a=3;
b=1;
c=1;
d=1;
e=1;
f=1;

fit [1:] f(x) 'LCVR_processed.dat' using 1:2 via a,b,c,d
set output "LCVR-retardance.eps"
plot 'LCVR_processed.dat' using 1:2 w l @st lc rgb "red" notitle
#, f(x) w l dashtype 2 lw 2 lc rgb "blue" title "Exponential fit"

reset
set style arrow 8 heads size screen 0.008,90 ls 2 lc rgb "black"
set style arrow 6 nohead ls 2 dt 2 lc rgb "black"
set arrow from 15,3.4 to 20,3.4 as 8
set arrow from 20,3.4 to 20,0.8 as 6
set label "5ms" at 16,3.6
set size 1,0.8
set xrange [-10:25]
set yrange [0:5]
set output "LCVR-switch-time.eps"
set xlabel "Time (ms)"
set ylabel "Amplitude (Volts)"
plot 'lcvr_response_on_off_on.dat' using ($1*1000):2 w l @st lc rgb "red" notitle